// A simple sketch to show the system alarm bar by 8 WS2812B LEDs.

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
 #include <avr/power.h> // Required for 16 MHz Adafruit Trinket
#endif

// Which pin on the Arduino is connected to the NeoPixels?
// On a Trinket or Gemma we suggest changing this to 1:
#define LED_PIN    0

// How many NeoPixels are attached to the Arduino?
#define LED_COUNT 8

// Declare our NeoPixel strip object:
Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);
// Argument 1 = Number of pixels in NeoPixel strip
// Argument 2 = Arduino pin number (most are valid)
// Argument 3 = Pixel type flags, add together as needed:
//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
//   NEO_GRB     Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB     Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
//   NEO_RGBW    Pixels are wired for RGBW bitstream (NeoPixel RGBW products)


String ssid = "";
String password = "";
int run_time = 0;
ESP8266WebServer server(80);


void server_handles() {

    //set the all the led with color specified in the post body, using colorWipe function
    server.on("/set", []() {
      String response = server.arg("plain");
      int volume = atoi(response.c_str());
      switch(volume){

      case 1:
      Serial.println("Red");
      colorWipe(strip.Color(255,   0,   0), 50);
      break ;
      case 2:
      Serial.println("Green");
      colorWipe(strip.Color(0,   255,   0), 10);
      break ;
      case 3:
      Serial.println("blue");
      colorWipe(strip.Color(0,   0,   255), 10);
      break ;
      }
    });

    //set the led in position of index with color specified in the the arguments of color_1, color_2, color_3
    server.on("/set_bit_color", []() {
      String index_string = server.arg("index");
      int index = atoi(index_string.c_str());
      String color_1_string = server.arg("color_1");
      int color_1 = atoi(color_1_string.c_str());
      String color_2_string = server.arg("color_2");
      int color_2 = atoi(color_2_string.c_str());
      String color_3_string = server.arg("color_3");
      int color_3 = atoi(color_3_string.c_str());
      set_bit_color(strip.Color(color_1,   color_2,   color_3), index);
    });

    //set the alarm status with colors of red and green
    server.on("/set_alarm_status", []() {
      run_time = 0;
      String status_string = server.arg("status");
      int status = atoi(status_string.c_str());
      for (int i = 0; i < 8; i++) {
        // 检查第i位是否为1
        if (status & (1 << i)) {
         set_bit_color(strip.Color(255,   0,   0), i); // 设置为红色 (HIGH)
          } else {
          set_bit_color(strip.Color(0,   255,   0), i); // 设置为绿色 (LOW)
            }
      }
      server.send(200, "text/plain", "successfully update alarm status!\r\n");
    });

}

// setup() function -- runs once at startup --------------------------------

void setup() {
  Serial.begin(115200);
  while (!Serial)  // Wait for the serial connection to be establised.
    delay(50);
  Serial.println();

    // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid,password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");

  IPAddress myIP = WiFi.localIP();
  Serial.println("IP address: ");
  Serial.println(myIP);

  if (!MDNS.begin("esp8266")) {             // Start the mDNS responder for esp8266.local
    Serial.println("Error setting up MDNS responder!");
  }
  Serial.println("mDNS responder started");

  server_handles();
  server.begin();
  Serial.println("HTTP server started");
  MDNS.addService("http", "tcp", 80);

  // These lines are specifically to support the Adafruit Trinket 5V 16 MHz.
  // Any other board, you can remove this part (but no harm leaving it):
#if defined(__AVR_ATtiny85__) && (F_CPU == 16000000)
  clock_prescale_set(clock_div_1);
#endif
  // END of Trinket-specific code.

  strip.begin();           // INITIALIZE NeoPixel strip object (REQUIRED)
  strip.show();            // Turn OFF all pixels ASAP
  strip.setBrightness(10); // Set BRIGHTNESS to about 1/5 (max = 255)
  colorWipe(strip.Color( 0,   0,   0), 50);
}


// loop() function -- runs repeatedly as long as board is on ---------------

void loop() {
  MDNS.update();
  server.handleClient();
  delay(50);
  run_time += 1;
  if (run_time >6000 ) {
    run_time = 0;
    colorWipe(strip.Color( 0,   0,   0), 50);
  }
}


// Some functions of our own for creating animated effects -----------------

// Fill strip pixels one after another with a color. Strip is NOT cleared
// first; anything there will be covered pixel by pixel. Pass in color
// (as a single 'packed' 32-bit value, which you can get by calling
// strip.Color(red, green, blue) as shown in the loop() function above),
// and a delay time (in milliseconds) between pixels.
void colorWipe(uint32_t color, int wait) {
  for(int i=0; i<strip.numPixels(); i++) { // For each pixel in strip...
    strip.setPixelColor(i, color);         //  Set pixel's color (in RAM)
    strip.show();                          //  Update strip to match
    delay(wait);                           //  Pause for a moment
  }
}

void set_bit_color(uint32_t color, int index) {
    strip.setPixelColor(index, color);         //  Set pixel's color (in RAM)
    strip.show();                          //  Update strip to match
}